Using a Custom POI Icons

This Sample will build on the previous sample.  The POI created for New York will utilize a custom icon rather than the default icon.

The Flash CS3 IDE should be opened displaying the AddPOI.fla file to perform the steps below.

1. Save the AddPOI.fla file as CustomIcon.fla.
2. Change the label on the button from New York to Custom Icon.
3. Save the file containing the class code as CustomIcon.as
4. Click the CustomIcon.fla tab
5. From the file menu select Publish Settings, click on the Flash tab and then the Settings... button
6. Enter CustomIcon in the document class field and click OK
7. Create a private variable, inside the class definition, to hold the NYC POI.
8. The code below replaces the constructor and the onButtonClick code from the previous example, and does the following
• In the constructor a POI for NYC is created and the map is centered on NYC. This POI will have a default Icon
• In the onButtonClick event handler a new ImageMapIcon is created and it is pointed to a url for the image
• The POI for NYC is then associated with the new Icon


private var nycPoi:Poi;

/**
* Constructor
*/
public function CustomIcon():void {

// Set Stage Properties
this.stage.scaleMode = StageScaleMode.NO_SCALE;
this.stage.align=StageAlign.TOP_LEFT;

// Handle Map Sizing
this.stage.addEventListener(Event.RESIZE, this.onStageResize);

// Create lat/lng point for NYC
var nycLL:PointLL = new PointLL(40.720409,-73.994637);

// Create Poi
nycPoi= new Poi(nycLL);
nycPoi.setInfoTitle("New York, New York");
nycPoi.setInfoContent("The city that never sleeps, That's why it looks that way in the morning");
nycPoi.setKey("A1");
myMap.addPoi(nycPoi);
myMap.setCenter(nycLL);

// Handle Resize event
this.stage.addEventListener(Event.RESIZE, this.onStageResize);

// Hanlde Button Click
myButton.addEventListener(MouseEvent.CLICK, onButtonClick);

// Set Initial size
onStageResize(null);
}

/**
* Handle Button Click
*/
private function onButtonClick(event:MouseEvent):void {

var nycIcon:ImageMapIcon = new ImageMapIcon();
nycIcon.setImageURL("http://www.yoursite.com/cs3/apple.jpg", 32, 32);
nycPoi.setIcon(nycIcon);
}


9. From the menu bar, select "File >> Export >> Export Movie..."
10. Run the application by browsing to the exported movie and double-clicking the CustomIcon.swf file.
11. Click on the Custom Icon button to see the Icon change from the default Icon to the image you selected.

IV. Geocoding, Routing, and Searching

Geocoding

This sample utilizes the MapQuest Geocode server to retreive geocode data for an address.

1. Open the Flash CS3 IDE.
2. From the menu bar, select "File >> New >> Flash File (ActionScript 3.0)"
3. From the Components toolbox, click and drag the Advantage API component to the stage.
4. From the Components toolbox, click and drag a label to the stage, and set its parameters as shown below.
• Text: City:
5. From the Components toolbox, click and drag a TextInput to the stage, and set its parameters as shown below.
• Instance Name: txtCity
6. Repeat steps 4-7 for state, zip and country.
7. From the Components toolbox, click and drag a button to the stage.
8. Click the Parameters tab relating to the Button component, and enter the values shown below.
• InstanceName: myButton
• Label: Geocode Address
9. From the Components toolbox, click and drag a TextArea to the stage, and enter the values shown below.
• Instance Name: myTextArea
10. Save newly created flash file as Geocode.fla
11. From the File menu select New and then ActionScript File from the resulting dialog box. Click OK.
12. Enter code below into the window that is opened.


package {

//import the required classes
import com.mapquest.*;
import flash.display.Sprite;
import flash.events.MouseEvent;

public class Geocode extends Sprite {


//create and set required variable to execute the geocode process
private var serverName:String = "geocode.access.mapquest.com";
private var serverPath:String = "mq";
private var serverPort:int = 80;
private var clientId:String = "[Your Client ID]";
private var password:String = "[Your Password]";
/**
* Constructor
*/
public function Geocode():void {

// Add listener for button click
myButton.addEventListener(MouseEvent.CLICK, onButtonClick);

}

/**
* Handle Button Click
*/
private function onButtonClick(event:MouseEvent):void {

var address:Address = new Address();
address.setCity(txtCity.text);
address.setState(txtState.text);
address.setPostalCode(txtZip.text);
address.setCountry(txtCountry.text);

// Setup server object for call.
var exec:Exec = new Exec(serverName, serverPath, serverPort);
exec.setClientId(clientId);
exec.setPassword(password);

// Add a listener to be called when geocode completes
exec.addEventListener(Exec.TRANS_TYPE_GEOCODE, onGeocode);

// Add a listener to the exec object. To handle the Geocode Error.
exec.addEventListener(Exec.EVENT_DO_TRANSACTION_ERROR, onExecError);
//call the geocode function of the exec object and give it the address object to be geocoded
exec.geocode(address);

}

/**
* Handle successful call to geocode service
*/
private function onGeocode(evt:ExecResultEvent):void {

//retreive the location collection from the event object.
var lc:LocationCollection = LocationCollection(evt.resultData);

//get the first geoaddress result out of the collection
var geoAddr:GeoAddress = GeoAddress(lc.get(0));

//build a nice string to show in the TextArea.
var str:String = "Lat: "+geoAddr.getLatLng().lat+" Lng: "+geoAddr.getLatLng().lng+" Resultcode: "+geoAddr.getResultCode()+"\n";
myTextArea.text="Geocode Results\n";
myTextArea.text += str;

}

/**
* Geocode Error - Handle errors.
*/
private function onExecError(e:ExecFaultEvent):void {

trace("Error retrieving data from the server. \n\nDid you set your Client Id and/or Password?", "Server Communication Error:");

}


} // End Class

} // End Package


13. Replace the instances of "Your Client ID" and "Your Password" with the your account information.
14. Save the file containing the above code as Geocode.as in the same folder as the .fla file.
15. Click the Geocode.fla tab.
16. From the file menu select Publish Settings, click on the Flash tab and then the Settings... button
17. Enter Geocode in the document class field and click OK
18. From the menu bar, select "File >> Export >> Export Movie..."
19. Run the application by browsing to the exported movie and double-clicking the Goecode.swf file.
20. Enter an address and click the Geocode Address Button

Geocode and Map

This sample will build on the previous sample. This sample utilizes the MapQuest Geocode servers to retreive geocode data for an address and places a POI on a map.

1. Save the Geocode.fla file as GeocodeAndMap.fla.
2. Save the Geocode.as file GeocodeAndMap.as
3. From the Components toolbox, click and drag a tileMap to the stage.
4. Click the Parameters tab relating to the TileMap component, and enter the values shown below.
• InstanceName: myMap
• mapType: map
• key: "Your User Key"
• zoomLevel: 4
5. Save newly created flash file as GeocodeAndMap.fla
6. Enter code below GeocodeAndMap.as file, overwriting the exisitng code.


package {

//import the required classes
import flash.display.Sprite;
import flash.display.StageScaleMode;
import flash.display.StageAlign;
import flash.events.MouseEvent;
import com.mapquest.*;
import com.mapquest.tilemap.pois.*;

public class GeocodeAndMap extends Sprite {

//create and set required variable to execute the geocode process
private var serverName:String = "geocode.access.mapquest.com";
private var serverPath:String = "mq";
private var serverPort:int = 80;
private var clientId:String = "[Your Client ID]";
private var password:String = "[Your Password]";

/**
* Constructor
*/
public function GeocodeAndMap():void {

// Set Stage Properties
this.stage.scaleMode = StageScaleMode.NO_SCALE;
this.stage.align=StageAlign.TOP_LEFT;

// Add listener for button click
myButton.addEventListener(MouseEvent.CLICK, onButtonClick);
}

/**
* Handle button click
*/
private function onButtonClick(e:MouseEvent):void {

var address:Address = new Address();
address.setCity(txtCity.text);
address.setState(txtState.text);
address.setPostalCode(txtZip.text);
address.setCountry(txtCountry.text);

// Setup server object for call.
var exec:Exec = new Exec(serverName, serverPath, serverPort);
exec.setClientId(clientId);
exec.setPassword(password);

// Add a listener to be called when geocode completes
exec.addEventListener(Exec.TRANS_TYPE_GEOCODE, onGeocode);

// Add a listener to the exec object. To handle the Geocode Error.
exec.addEventListener(Exec.EVENT_DO_TRANSACTION_ERROR, onExecError);

//call the geocode function of the exec object and give it the address object to be geocoded
exec.geocode(address);

}

/**
* Handle successful call to geocode service
*/
private function onGeocode(evt:ExecResultEvent):void {

//retreive the location collection from the event object.
var lc:LocationCollection = LocationCollection(evt.resultData);

//get the first geoaddress result out of the collection
var geoAddr:GeoAddress = GeoAddress(lc.get(0));

//build a nice string to show in the TextArea.
var str:String = "Lat: "+geoAddr.getLatLng().lat+" Lng: "+geoAddr.getLatLng().lng+" Resultcode: "+geoAddr.getResultCode()+"\n";

myTextArea.text="Geocode Results\n";
myTextArea.text += str;

// Create a POI for the address.
var poi:Poi = new Poi(geoAddr.getLatLng());
poi.setInfoTitle(geoAddr.getStreet());
poi.setInfoContent(geoAddr.getResultCode());

// Place the POI on the map and recenter
myMap.addPoi(poi);
myMap.setCenter(poi.getLatLng(),7);
}

/**
* Geocode Error - Handle errors.
*/
private function onExecError(e:ExecFaultEvent):void {

trace("Error retrieving data from the server. \n\nDid you set your Client Id and/or Password?", "Server Communication Error:");
}

} // End Class

} // End Package


7. Enter your Client ID and Password in the appropriate places in the GeocodeAndMap.as file.
8. Click the GeocodeAndMap.fla tab.
9. From the file menu select Publish Settings, click on the Flash tab and then the Settings... button
10. Enter GeocodeAndMap in the document class field and click OK
11. From the menu bar, select "File >> Export >> Export Movie..."
12. Run the application by browsing to the exported movie and double-clicking the GeocodeAndMap.swf file.
13. Enter an address and click the Geocode Address Button

Geocoding Multiple Addresses

This sample utilizes the MapQuest Geocode servers to retreive geocode data for two addresses.

1. Open the Flash CS3 IDE.
2. From the menu bar, select "File >> New >> Flash File (ActionScript 3.0)"
3. From the Components toolbox, click and drag an Advantage API component to the stage.
4. From the Components toolbox, click and drag a label to the stage, and enter its parameters as shown below.
• Text: Street:
5. From the Components toolbox, click and drag a TextInput to the stage, and enter ts parameters as shown below.
• InstanceName: txtStreet1
6. Repeat steps 4-7 for city, state, zip and country.
7. Repeat steps 4-7 again for street, city, state, zip and country, replacing the 1 at the end of the instance name with a 2.
8. From the Components toolbox, click and drag a button to the stage.
9. Click the Parameters tab relating to the Button component, and enter the values shown below.
• InstanceName: myButton
• Label: Geocode Addresses
10. From the Components toolbox, click and drag a TextArea to the stage, and give it an instance name of txtResults.
11. Save newly created flash file as BatchGeocode.fla
12. From the File menu select New and then ActionScript File from the resulting dialog box. Click OK.
13. Enter code below into the window that is opened.


package {

//import the required classes
import flash.display.Sprite;
import flash.display.StageScaleMode;
import flash.display.StageAlign;
import flash.events.MouseEvent;
import com.mapquest.*;

public class BatchGeocode extends Sprite {
//create and set required variable to execute the geocode process
private var serverName:String = "geocode.access.mapquest.com";
private var serverPath:String = "mq";
private var serverPort:int = 80;
private var clientId:String = "[Your Client ID]";
private var password:String = "[Your Password]";

/**
* Constructor
*/
public function BatchGeocode():void {

// Set Stage Properties
this.stage.scaleMode = StageScaleMode.NO_SCALE;
this.stage.align=StageAlign.TOP_LEFT;

// Add listener for button click
myButton.addEventListener(MouseEvent.CLICK, onButtonClick);
}

/**
* Handle button click
*/
public function onButtonClick(evt:MouseEvent):void {

// Create an empty location collection to hold the addresses that
var lc:LocationCollection = new LocationCollection();

// Create an empty address object.
var address1:Address = new Address();

//populate the address object with the information from the form
address1.setStreet(this.txtStreet1.text);
address1.setCity(this.txtCity1.text);
address1.setState(this.txtState1.text);
address1.setPostalCode(this.txtZip1.text);
address1.setCountry(this.txtCountry1.text);

// Add the address to the location collection created above
lc.add(address1);

//populate the address object with the information from the form
var address2:Address = new Address();
address2.setStreet(this.txtStreet2.text);
address2.setCity(this.txtCity2.text);
address2.setState(this.txtState2.text);
address2.setPostalCode(this.txtZip2.text);
address2.setCountry(this.txtCountry2.text);

// Add the address to the location collection created above
lc.add(address2);

// Setup server object for call.
var exec:Exec = new Exec(serverName, serverPath, serverPort);
exec.setClientId(clientId);
exec.setPassword(password);

// Add a listener to be called when batch geocode completes
exec.addEventListener(Exec.TRANS_TYPE_BATCH_GEOCODE, onBatchGeocode);

// Add a listener to the exec object. To handle the Geocode response - Error.
exec.addEventListener(Exec.EVENT_DO_TRANSACTION_ERROR, onExecError);

// call the batch geocode function of the exec object. Passing it the location collection
exec.batchGeocode(lc);

}

/**
* Handle successful call to batchGeocode service
*/
private function onBatchGeocode(evt:ExecResultEvent):void {
var str:String = "";

// Get the locationCollectionCollection
var lcc:LocationCollectionCollection = LocationCollectionCollection(ExecResultEvent(evt).resultData);

// Loop through all the locationCollections in my collectionCollection
for (var i:int=0; i < lcc.getSize(); i++){
// Get the 1st for each location collection.
var geoAddr:GeoAddress = LocationCollection(lcc.getAt(i)).getAt(0);

// Build a nice string to display the data
str += "Lat: "+geoAddr.getLatLng().lat+ " Lng: " +
geoAddr.getLatLng().lng+" Resultcode: "+geoAddr.getResultCode() + "\n";
}

// update results.
this.txtResults.text += str;
}

/**
* BatchGeocode Error - Handle errors.
*/
private function onExecError(e:ExecFaultEvent):void {
trace("Error retrieving data from the server. \n\nDid you set your Client Id and/or Password?", "Server Communication Error:");
}


} // End Class

} // End Package


14. Save the file containing the above code as BatchGeocode.as in the same folder as the .fla file.
15. Click the BatchGeocode.fla tab.
16. From the file menu select Publish Settings, click on the Flash tab and then the Settings... button
17. Enter BatchGeocode in the document class field and click OK
18. From the menu bar, select "File >> Export >> Export Movie..."
19. Run the application by browsing to the exported movie and double-clicking the BatchGoecode.swf file.
20. Enter addresses and click the Geocode Addresses Button

Calculate Route

This sample will utilize the previous sample and the MapQuest Geocoding and Routing servers to calculate a route between two addresses.

1. Save the BatchGeocode.fla file as DoRoute.fla.
2. Save the BatchGeocode.as file as DoRoute.as.
3. Click the Parameters tab relating to the Button component, and enter the values shown below.
• InstanceName: myButton
• Label: Calculate Route
4. From the Components toolbox, click and drag a DataGrid to the stage, and give it an instance name of myDataGrid.
5. Replace the code in the DoRoute.as file with the code shown below.


package {

import fl.controls.DataGrid;
import flash.display.*;
import flash.events.MouseEvent;
import com.mapquest.*;

public class DoRoute extends Sprite {

// Server for geocoding.
private var geoCodeServerName:String = "geocode.access.mapquest.com";
private var geoCodeServerPath:String = "mq";
private var geoCodeServerPort:int = 80;

// Server for routing.
private var routeServerName:String = "route.access.mapquest.com";
private var routeServerPath:String = "mq";
private var routeServerPort:int = 80;

// Client Id and password
private var clientId:String = "[Your Client ID]";
private var password:String = "[Your Password]";

// Exec server object
private var exec:Exec;

/**
* Constructor
*/
public function DoRoute():void {
// Set Stage Properties
this.stage.scaleMode = StageScaleMode.NO_SCALE;
this.stage.align=StageAlign.TOP_LEFT;

// Add Listener for button.
myButton.addEventListener(MouseEvent.CLICK, onButtonClick);
}

/**
* Handle button click
*/
public function onButtonClick(e:MouseEvent):void {

// Create an empty location collection to hold the addresses.
var lc:LocationCollection = new LocationCollection();

// Create an empty address object.
var address1:Address = new Address();

//populate the address object with the information from the form
address1.setStreet(this.txtStreet1.text);
address1.setCity(this.txtCity1.text);
address1.setState(this.txtState1.text);
address1.setPostalCode(this.txtZip1.text);
address1.setCountry(this.txtCountry1.text);

// Add the address to the location collection created above
lc.add(address1);

//populate the address object with the information from the form
var address2:Address = new Address();
address2.setStreet(this.txtStreet2.text);
address2.setCity(this.txtCity2.text);
address2.setState(this.txtState2.text);
address2.setPostalCode(this.txtZip2.text);
address2.setCountry(this.txtCountry2.text);

// Add the address to the location collection created above
lc.add(address2);

// Set up connection for geocode server
exec = new Exec(geoCodeServerName, geoCodeServerPath, geoCodeServerPort);
exec.setClientId(clientId);
exec.setPassword(password);

// Add a listener to be called when batch geocode completes
exec.addEventListener(Exec.TRANS_TYPE_BATCH_GEOCODE, onBatchGeocode);

// Add a listener to the exec object. To handle the Geocode response - Error.
exec.addEventListener(Exec.EVENT_DO_TRANSACTION_ERROR, onBatchGeocodeError);

// Geocode all addresses involved.
exec.batchGeocode(lc);
}

/**
* Handle successful response to BatchGeocode service call
*/
private function onBatchGeocode(evt:ExecResultEvent):void {
var lcc:LocationCollectionCollection = LocationCollectionCollection(evt.resultData);
var lc:LocationCollection = new LocationCollection();

// Extract the geocoded address from the collection of location collections
for (var i:int=0; i < lcc.getSize(); i++) {
lc.add(GeoAddress(LocationCollection(lcc.get(i)).get(0)));
}

/*
Take the goecoded addresses and calculate the route.
*/
// Set up connection for route server
exec = new Exec(routeServerName, routeServerPath, routeServerPort);
exec.setClientId(clientId);
exec.setPassword(password);

// Add Listeners for route calculation
exec.addEventListener(Exec.TRANS_TYPE_DOROUTE, onDoRoute);
exec.addEventListener(Exec.EVENT_DO_TRANSACTION_ERROR, onRouteCalcError);

// Create an empty RouteOptions object;
var routeOptions:RouteOptions = new RouteOptions();

// Make the call
exec.doRoute(lc, routeOptions, null);
}

/**
* Handle successful response to DoRoute service call
*/
private function onDoRoute(evt:ExecResultEvent):void {
var rr:RouteResults = RouteResults(evt.resultData);
var treks:TrekRouteCollection = rr.getTrekRoutes();
var maneuvers:ManeuverCollection = TrekRoute(treks.get(0)).getManeuvers();

// Populate grid with results
myDataGrid.rowCount = maneuvers.getSize();
myDataGrid.columns = ["Route Instructions", "Distance (miles)", "Time (mins)"];
var oS:String=new String();
for (var i:int = 0; i < maneuvers.getSize(); i++) {
var maneuver:Maneuver = Maneuver(maneuvers.get(i));
var d:String= (Math.round(maneuver.getDistance() * 10) / 10 ).toString();
var t:String= (Math.round((maneuver.getTime()/60) * 10) / 10 ).toString();
var ro:Object = { "Route Instructions":maneuver.getNarrative(),"Distance (miles)":d,"Time (mins)":t };
myDataGrid.addItem(ro);
}
}

/**
* BatchGeocode Error - Handle errors.
*/
private function onBatchGeocodeError(e:ExecFaultEvent):void {
trace("Error retrieving data from the server. \n\nDid you set your Client Id and/or Password?", "Server Communication Error:");
}

/**
* Route Calculation Error - Handle errors.
*/
private function onRouteCalcError(e:ExecFaultEvent):void {
trace("Error retrieving data from the server", "Error:");
}

} // End Class

} // End Package


6. Replace the instances of "Your ClientID" and "Your Password", in the DoRoute.as file, with the proper information from your account.
7. Save the file containing the above code as DoRoute.as in the same folder as the .fla file.
8. Click the DoRoute.fla tab.
9. From the file menu select Publish Settings, click on the Flash tab and then the Settings... button
10. Enter DoRoute in the document class field and click OK
11. From the menu bar, select "File >> Export >> Export Movie..."
12. Run the application by browsing to the exported movie and double-clicking the DoRoute.swf file.
13. Enter addresses and click the Calculate Route Button

Display Route

This sample will utilize the previous sample and the MapQuest Geocoding, Routing and Mapping servers to calculate a route between two addresses and display it as an ovelay on a map.

1. Save the DoRoute.fla file as OverlayRouteMap.fla.
2. Select the DataGrid component in the OverlayRouteMap.fla file and delete it.
3. Drag a Tilemap component onto the stage.
4. Click the Parameters tab relating to the TileMap component, and enter the values shown below.
• InstanceName: myMap
• mapType: map
• key: "Your User Key"
5. Save the DoRoute.as file as OverlayRouteMap.as.
6. Replace the code in the OverlayRouteMap.as file with the code below.


package {

//import the required classes
import flash.display.Stage;
import flash.display.StageAlign;
import flash.display.StageScaleMode;
import fl.controls.DataGrid;
import flash.display.*;
import flash.events.MouseEvent;
import com.mapquest.*;
import com.mapquest.tilemap.overlays.*;

public class OverlayRouteMap extends Sprite {
// Server for geocoding.
private var geoCodeServerName:String = "geocode.access.mapquest.com";
private var geoCodeServerPath:String = "mq";
private var geoCodeServerPort:int = 80;

// Server for Routing
private var routeServerName:String = "route.access.mapquest.com";
private var routeServerPath:String = "mq";
private var routeServerPort:int = 80;

// Client Id and password
private var clientId:String = "[Your Client ID]";
private var password:String = "[Your Password]";

// Exec server object
private var exec:Exec;

/**
* Constructor
*/
public function OverlayRouteMap():void {
// Set Stage Properties
this.stage.scaleMode = StageScaleMode.NO_SCALE;
this.stage.align=StageAlign.TOP_LEFT;

// Add Listener for button.
myButton.addEventListener(MouseEvent.CLICK, onButtonClick);
}

/**
* Handle button click
*/
public function onButtonClick(e:MouseEvent):void {
// Create an empty location collection to hold the addresses that
var lc:LocationCollection = new LocationCollection();

// Create an empty address object.
var address1:Address = new Address();

//populate the address object with the information from the form
address1.setStreet(this.txtStreet1.text);
address1.setCity(this.txtCity1.text);
address1.setState(this.txtState1.text);
address1.setPostalCode(this.txtZip1.text);
address1.setCountry(this.txtCountry1.text);

// Add the address to the location collection created above
lc.add(address1);

//populate the address object with the information from the form
var address2:Address = new Address();
address2.setStreet(this.txtStreet2.text);
address2.setCity(this.txtCity2.text);
address2.setState(this.txtState2.text);
address2.setPostalCode(this.txtZip2.text);
address2.setCountry(this.txtCountry2.text);

// Add the address to the location collection created above
lc.add(address2);

// Set up connection for geocode server
exec = new Exec(geoCodeServerName, geoCodeServerPath, geoCodeServerPort);
exec.setClientId(clientId);
exec.setPassword(password);

// Add a listener to be called when batch geocode completes
exec.addEventListener(Exec.TRANS_TYPE_BATCH_GEOCODE, onBatchGeocode);

// Add a listener to the exec object. To handle the Geocode response - Error.
exec.addEventListener(Exec.EVENT_DO_TRANSACTION_ERROR, onBatchGeocodeError);

// Geocode all addresses involved.
exec.batchGeocode(lc);
}

/**
* Handle successful response to BatchGeocode service call
*/
private function onBatchGeocode(evt:ExecResultEvent):void {
//Get the location collection collection from the event.
var lcc:LocationCollectionCollection = LocationCollectionCollection(evt.resultData);

// Create a LocationCollection for geocoded addresses.
var lc:LocationCollection = new LocationCollection();

// Get the geocoded addresses from the location collections
for (var i:int=0; i < lcc.getSize(); i++) {
lc.add(GeoAddress(LocationCollection(lcc.get(i)).get(0)));
}

// Create an exec object this time pointing the routing server.
var exec:Exec = new Exec(routeServerName, routeServerPath, routeServerPort);
exec.setClientId(clientId);
exec.setPassword(password);

// Create an empty route options object
var routeOptions:RouteOptions = new RouteOptions();

// Set the maxShapePoints property to 10000. Just to be safe.
routeOptions.setMaxShapePointsPerManeuver(10000);

// Add listeners to receive the results of thie call.
exec.addEventListener(Exec.TRANS_TYPE_DOROUTE, onDoRoute);
exec.addEventListener(Exec.EVENT_DO_TRANSACTION_ERROR, onRouteCalcError);

// Make the call
exec.doRoute(lc, routeOptions, null);
}

/**
* Handle successful response to DoRoute service call
*/
private function onDoRoute(evt:ExecResultEvent):void {
// Extract the RouteResults object from the event data.
var rr:RouteResults = RouteResults(evt.resultData);

// Get the shape points from the routeResults object
var shapes:IPointLLCollection = rr.getShapePoints();

// Get rid of previous overlays
myMap.removeAllOverlays();

// If a route has been calculated then create an overlay and place it on the map
if (shapes.getSize() != 0 ) {
// Create a line overlay and set it's display properties
var lo:LineOverlay = new LineOverlay();
lo.setBorderWidth(10);
lo.setColor(0x0000ff);
lo.setColorAlpha(.4);
lo.setShapePoints(shapes);

// Add the line overlay to the map
myMap.addOverlay(lo);

// set zoom to the center of the route.
myMap.zoomToRect(new RectLL(shapes.getPointLL(0), rr.getShapePoints().getPointLL(shapes.getSize()-1)));
}

}

/**
* BatchGeocode Error - Handle errors.
*/
private function onBatchGeocodeError(e:ExecFaultEvent):void {
trace("Error retrieving data from the server. \n\nDid you set your Client Id and/or Password?", "Server Communication Error:");
}

/**
* Handle error getting route
*/
private function onRouteCalcError(e:ExecFaultEvent):void {
trace("Error retrieving data from the server", "Error:");
}


} // End Class

} // End Package


7. Replace the Client ID and Password fields in the code above with the appropriate values from your account.
8. Click the tab containing the OverlayRouteMap.fla file.
9. From the file menu select Publish Settings, click on the Flash tab and then the Settings... button
10. Enter OverlayRouteMap in the document class field and click OK
11. From the menu bar, select "File >> Export >> Export Movie..."
12. Run the application by browsing to the exported movie and double-clicking the OverlayRouteMap.swf file.
13. Enter addresses and click the Calculate Route Button

Displaying Search Results on a Map

This sample will utilize the Geocoding sample (from earlier in this guide), and the MapQuest Geocoding, Spatial Searching, and Mapping servers to display search results on a map.

1. Open the Geocode.as file and save it as SearchAndMap.as.
2. Open the Geocode.fla file and save it as SearchAndMap.fla.
3. Select the text area on the stage and delete it.
4. From the Components toolbox, click and drag a label to the stage, and assign the parameters shown below.
• Text: Radius:
5. From the Components toolbox, click and drag a TextInput to the stage, and assign the parameters shown below.
• InstanceName: txtRadius
6. From the Components toolbox, click and drag a label to the stage, and assign the parameters shown below.
• Text: Distance Units:
7. From the Components toolbox, click and drag a ComboBox to the stage, and assign the parameters shown below.
• InstanceName: distanceUnitsCombo
8. From the Components toolbox, click and drag a label to the stage, and assign the parameters shown below.
• Text: Max Results:
9. From the Components toolbox, click and drag a TextInput to the stage, and assign the parameters shown below.
• InstanceName: txtMaxResults
10. Click the "Geocode Address" button on the stage, and change its label to the value shown below.
• Label: Search
11. From the Components toolbox, click and drag a tileMap to the stage.
12. Click the Parameters tab relating to the TileMap component, and enter the values shown below.
• InstanceName: myMap
• mapType: map
• key: "Your User Key"
• zoomLevel: 4
13. Replace the code in the SearchAndMap.as file with the code shown below.


package {

import flash.display.Stage;
import flash.display.StageAlign;
import flash.display.StageScaleMode;
import com.mapquest.*;
import com.mapquest.tilemap.controls.LargeZoomControl;
import com.mapquest.tilemap.pois.*;
import fl.data.DataProvider;
import flash.display.*;
import flash.events.MouseEvent;

public class SearchAndMap extends Sprite {
// Server for geocoding.
private var geocodeServerName:String = "geocode.access.mapquest.com";
private var geocodeServerPort:int = 80;
private var geocodeServerPath:String = "mq";

// Server for search calculation.
private var searchServerName:String = "spatial.access.mapquest.com";
private var searchServerPort:int = 80;
private var searchServerPath:String = "mq";

// Client Id and password
private var clientId:String = "[Your Client ID]";
private var password:String = "[Your Password]";

// Geocoded address
private var geocodedAddress:GeoAddress;

/**
* Constructor
*/
public function SearchAndMap():void {
// Set Stage Properties
this.stage.scaleMode = StageScaleMode.NO_SCALE;
this.stage.align=StageAlign.TOP_LEFT;

// Populate combo box
var distanceUnits:DataProvider = new DataProvider()
distanceUnits.addItem( {label:"Miles", data:Constants.DISTANCEUNITS_MILES} );
distanceUnits.addItem( {label:"Kilometers", data:Constants.DISTANCEUNITS_KILOMETERS} );
distanceUnitsCombo.dataProvider = distanceUnits;

// Add listener for button click
myButton.addEventListener(MouseEvent.CLICK, onSearchClick);

// Add Zoom control to map
myMap.addControl( new LargeZoomControl());
}

/**
* Call Search service when SearchButton is clicked.
*/
private function onSearchClick(e:MouseEvent):void {
// Geocode address.
var address:Address = new Address();

// populate the address object with the information from the form
//address.setStreet(this.txtStreet.text);
address.setCity(this.txtCity.text);
address.setState(this.txtState.text);
address.setPostalCode(this.txtZip.text);
address.setCountry(this.txtCountry.text);

// Create an exec object for the geocode call
var exec:Exec = new Exec(geocodeServerName, geocodeServerPath, geocodeServerPort);
exec.setClientId(clientId);
exec.setPassword(password);

// Add Listeners for Geocode call
exec.addEventListener(Exec.TRANS_TYPE_GEOCODE, onGeocodeAddress);
exec.addEventListener(Exec.EVENT_DO_TRANSACTION_ERROR, onGeocodeError);

//call the geocode function of the exec object - give it the address object to be geocoded
exec.geocode(address);
}

/**
* Handle successful response to Geocode service call
*/
private function onGeocodeAddress(evt:ExecResultEvent):void {
//Get the 1st geoaddress result out of the collection
var lc:LocationCollection = LocationCollection(evt.resultData);
geocodedAddress = GeoAddress(lc.get(0));

// Create an exec object for the Search Call
var exec:Exec = new Exec(searchServerName, searchServerPath, searchServerPort);
exec.setClientId(clientId);
exec.setPassword(password);

// Add listener for the search call.
exec.addEventListener(Exec.TRANS_TYPE_SEARCH, onSearch);
exec.addEventListener(Exec.EVENT_DO_TRANSACTION_ERROR, onSearchError);

// Create objects required for search parameters
var distanceUnits:DistanceUnits = new DistanceUnits(distanceUnitsCombo.selectedItem["data"]);
var searchCriteria:RadiusSearchCriteria = new RadiusSearchCriteria();

// Set the center of the search to the address entered.
searchCriteria.setCenter(geocodedAddress.getLatLng());

// Set Maximum matches
searchCriteria.setMaxMatches(int(Number(txtMaxResults.text)));

// Set the distance units value
searchCriteria.setRadius(Number(txtRadius.text), distanceUnits);

// Create a query object.
var dbLayerQueryCollection:DBLayerQueryCollection = new DBLayerQueryCollection();
var dbLayerQuery:DBLayerQuery = new DBLayerQuery();
dbLayerQuery.setDBLayerName("MQA.test");
dbLayerQueryCollection.add(dbLayerQuery);

// call the search function of the exec object
exec.search(searchCriteria, "", dbLayerQueryCollection);
}

/**
* Handle successful response from the Search service call.
*/
private function onSearch(evt:ExecResultEvent):void {
// Clear All Pois
myMap.removeAllPois();

// Get the feature collection from the event.
var fc:FeatureCollection = FeatureCollection(evt.resultData);

// Get each feature (which is a poi) from the collection and add it to the map.
for ( var i:int = 0; i < fc.getSize(); i++ ) {
var pointFeature:PointFeature = PointFeature(fc.get(i));

// Create a POI object and set it's location.
var poi:Poi = new Poi(pointFeature.getCenterLatLng());

// Set rollover and popup text.
poi.setInfoTitle(pointFeature.getName());
poi.setInfoContent(pointFeature.getCenterLatLng().lat + ' by ' +
pointFeature.getCenterLatLng().lng + '\n Distance: ' +
pointFeature.getDistance());
poi.setKey(pointFeature.getKey());

// Add the Poi to the map.
myMap.addPoi(poi);
}

//Add the search origin
poi = new Poi(geocodedAddress.getLatLng());
poi.setInfoTitle(geocodedAddress.getStreet() + ' ' + geocodedAddress.getCity());
poi.setInfoContent(geocodedAddress.getResultCode());
poi.setKey('Origin');
myMap.addPoi(poi);

//Best-Fit the map to the results
myMap.bestFit();
}

/**
* Geocode Error - Handle error from geocode call.
*/
private function onGeocodeError(e:ExecFaultEvent):void {
trace("Error retrieving data from the server. \n\nDid you set your Client Id and/or Password?", "Server Communication Error:");
}

/**
* Search Error - Handle error from search call.
*/
private function onSearchError(e:ExecFaultEvent):void {
trace("Error performing search. \n\nCheck server names.");
}


} // End Class

} // End Package


14. Replace the Client ID and Password in the above code block with eh proper information for your account.
15. Click the tab containing the SearchAndMap.fla file.
16. From the file menu select Publish Settings, click on the Flash tab and then the Settings... button
17. Enter SearchAndMap in the document class field and click OK
18. From the menu bar, select "File >> Export >> Export Movie..."
19. Run the application by browsing to the exported movie and double-clicking the SearchAndMap.swf file.
20. Enter addresses and click the Calculate Route Button